*title L's Short Story: Nursing Through the Fever
*author Whizumi
*scene_list
	startup

*create gender ""
*create name ""
*create plural false

*create L_gen 1
*create lex_gender ""

*create lex_name ""
*create lex_him ""
*create lex_his ""
*create lex_hrs ""
*create lex_she ""
*create lex_man ""
*create lex_dat ""

*create mc_him ""
*create mc_his ""
*create mc_hrs ""
*create mc_she ""
*create mc_man ""
*create mc_son ""
*create mc_sib ""
*create mc_mrs ""

*create man_him "him"
*create man_his "his"
*create man_hrs "his"
*create man_she "he"

*image Shortstories.jpg
*page_break Begin the story
You're…

*fake_choice
	#…a man. [He/Him.]
		*set gender "male"
		*goto gender_mc
	#…a woman. [She/Her.]
		*set gender "female"
		*goto gender_mc
	#…a person. [They/Them.]
		*set gender "non-binary"
		*goto gender_mc

*label gender_mc
*if (gender = "male")
	*set mc_him "him"
	*set mc_his "his"
	*set mc_she "he"
	*set mc_man "man"
	*set mc_son "son"
	*set mc_sib "brother"
	*set mc_mrs "Mr."
	*goto name
*elseif (gender = "female")
	*set mc_him "her"
	*set mc_his "her"
	*set mc_she "she"
	*set mc_man "woman"
	*set mc_son "daughter"
	*set mc_sib "sister"
	*set mc_mrs "Ms."
	*goto name
*elseif (gender = "non-binary")
	*set mc_him "them"
	*set mc_his "their"
	*set mc_she "they"
	*set mc_man "person"
	*set mc_son "child"
	*set mc_sib "sibling"
	*set mc_mrs "Mx."
	*set plural true
	*goto name

*label name
[Please enter a first name / shortened name.]

*fake_choice
	*if (gender = "female") #Aurelia.
		*set name "Aurelia"
	*if (gender = "female") #Dahlia.
		*set name "Dahlia"
	*if (gender = "female") #Caroline.
		*set name "Caroline"		
	*if (gender = "female") #Noelani.
		*set name "Noelani"
	*if (gender = "female") #Regina.
		*set name "Regina"
	*if (gender = "female") #Sabine.
		*set name "Sabine"		
	*if (gender = "male") #Alan.
		*set name "Alan"
	*if (gender = "male") #Elijah.
		*set name "Elijah"
	*if (gender = "male") #Kieran.
		*set name "Kieran"
	*if (gender = "male") #Noah.
		*set name "Noah"
	*if (gender = "male") #Oliver.
		*set name "Oliver"
	*if (gender = "male") #Reuben.
		*set name "Reuben"
	*if (gender = "non-binary") #Alex.
		*set name "Alex"
	*if (gender = "non-binary") #Carmen.
			*set name "Carmen"
	*if (gender = "non-binary") #June.
		*set name "June"
	*if (gender = "non-binary") #Kim.
			*set name "Kim"
	*if (gender = "non-binary") #River.
		*set name "River"
	*if (gender = "non-binary") #Quinn.
		*set name "Quinn"
	#None of these.
		*goto input_name
*goto L_gender

*label input_name
Input first name \ shortened name.

*input_text name
Your name is $!{name}, is that right?
*set name "${name}"

*choice
	#Yes.
		*goto L_gender
	#No.
		*goto input_name
*goto L_gender

*label L_gender
Your best friend…

*choice
	#…Lex Conlan is always there when you need it the most.
		*set lex_gender "male"
		*set L_gen 1
		*goto lex_gender
	#…Lexie Conlan is always there when you need it the most.
		*set lex_gender "female"
		*set L_gen 2
		*goto lex_gender
*finish

*label lex_gender
*if (lex_gender = "male")
	*set lex_name "Lex"
	*set lex_him "him"
	*set lex_his "his"
	*set lex_hrs "his"
	*set lex_she "he"
	*set lex_man "man"
	*set lex_dat "boyfriend"
	*goto start
*elseif (lex_gender = "female")
	*set lex_name "Lexie"
	*set lex_him "her"
	*set lex_his "her"
	*set lex_hrs "hers"
	*set lex_she "she"
	*set lex_man "woman"
	*set lex_dat "girlfriend"
	*goto start
*goto start

*label start
[b]Now playing as ${lex_name}.[/b]

${lex_name} stares at ${lex_his} tired reflection in the changing room mirror before closing ${lex_his} locker with a heavy sigh.

[i]Another shift is over…[/i]

Being a police officer is not an easy job, but since ${lex_she} and $!{name} stopped being partners, every shift feels extremely draining, 
making ${lex_him} acutely aware of how everything has become harder without $!{name} by ${lex_his} side.

[i]It's almost pathetic,[/i] ${lex_name} thinks, to be so attached to someone that their absence still makes everything seem harder, 
even though it's been months since $!{name} officially became a detective and even longer since ${mc_she} stopped being ${lex_his} full-time partner to pursue advanced training for the new role.

Yet, ${lex_name}'s longing to be near ${mc_him} hasn't faded; if anything, it has grown stronger. [i]How could it be any other way when—[/i]

$!{lex_she} shakes ${lex_his} head, refusing to finish that thought. It's time to go home—alone again, without $!{name}. How ${lex_she} wishes ${lex_she} could go home with ${mc_him}, 
just like the old days when they would drive home together…

*page_break But that's not going to happen, certainly not today.
It feels like a mockery, knowing that $!{name} is just on the other end of the department but having no reason to interact with ${mc_him}, 
not wanting to distract ${mc_him} from a job that suits ${mc_him} better, in which ${mc_she} could be happy.

And $!{name}'s happiness is important to ${lex_him}; of course it is. But there's another part of ${lex_him}—something selfish and ugly—that whispers it won't be enough, 
especially when ${lex_his} longing to be by ${mc_his} side is so intense it's almost unbearable.

Yet there's nothing ${lex_she} can do, so ${lex_she} takes a deep, calming breath and proceeds towards the exit.

Saying goodbye to a few colleagues along the way, ${lex_she} steps out of the changing room only to notice Parker standing nearby, 
${mc_his} gaze brightens as ${mc_she} @{plural spot|spots} ${lex_him} as well.

"Waiting for someone?" ${lex_name} asks, stepping closer.

Parker gives ${lex_him} a weak smile. "Yes. You," ${mc_she} @{plural reply|replies}, causing ${lex_name} to pause, confused.

Although Parker had been ${lex_his} partner for quite some time now, their communication had been purely work-related. 

Lately, however, ${lex_she} noticed that Parker was making more of an effort to be friendly with ${lex_him}.
It makes ${lex_him} feel guilty, knowing that ${lex_his} aloofness isn't ${mc_his} fault. 

Still, ${lex_she} isn't ready for this, not when ${lex_she} can't stop thinking about $!{name}, 
and the thought of unwittingly trying to replace ${mc_him} makes any friendly interaction with Parker feel wrong.

*page_break
"I'm sorry to bother you, but… Can I ask you to give me a ride?" Parker asks, interrupting ${lex_his} thoughts. "If you don't mind and have time, of course. It's just—"

"Hey, kiddo!" A familiar voice calls out, accompanied by a clap on ${lex_his} shoulder.

${lex_name} turns in surprise. "Mr. Bergmann?"

Parker nods in greeting, and Klemens chuckles warmly.

"At ease, officers," ${man_she} says, turning to ${lex_name}. "Mind walking with an old man, will you?"

Despite the casual tone and seemingly ordinary request, Klemens already guides ${lex_him} away from the exit, making ${lex_name} immediately realize something is wrong. "Is $!{name}—"

"Not now, kiddo," Klemens interrupts calmly, and ${lex_name} purses ${lex_his} lips but nods, feeling ${lex_his} partner's expectant gaze as ${lex_she} shifts ${lex_his} attention to ${mc_him}.

"I can wait in reception if that's okay," ${mc_she} @{plural say|says} with a small, strained smile.

"Sorry, Officer, but I'm afraid I'll need your partner for quite some time," Klemens replies before ${lex_name} can, confirming ${lex_name}'s growing worry.

$!{lex_his} posture stiffens involuntarily, a reaction that Klemens feels through the grip on ${lex_his} shoulder. 
$!{man_she} gives it a reassuring squeeze before letting go and turning to walk in the opposite direction of the exit.

*page_break
"I'll see you tomorrow," ${lex_name} says quickly to Parker, turning away before ${lex_she} can notice ${mc_his} evident disappointment as ${lex_she} hurries to catch up with Klemens.

$!{lex_his} anxiety pulses with each step as ${lex_she} follows $!{name}'s mentor, whose deliberate and heavy strides make it hard for ${lex_name} to keep up with ${man_him} due to ${man_his} large frame.

When they finally reach the investigation division, ${lex_name}, unable to remain silent any longer, finally asks, "Mr. Bergmann, is $!{name} alright?"

$!{lex_she} notices the slight tension in Klemens' shoulders before ${man_she} responds, "$!{name} hasn't been feeling well since this morning. $!{mc_she}, of course, 
@{plural insist|insists} ${mc_she}'@{plural re|s} fine, but it's obvious that ${mc_she}'@{plural re|s} not."

${lex_name}'s heart clenches at ${man_his} words, causing a rush of anxiety to squeeze ${lex_his} chest tighter. But before ${lex_she} can ask what happened, 
Klemens anticipates ${lex_his} question.

"Nothing serious, don't worry," Klemens says, leading the way to $!{name}'s office. "A few days ago, we had to stay at the factory freezer for quite some time during our investigation, 
so it's probably just a cold. Still, I don't want ${mc_him} going home alone in this state."

${lex_name} nods, concern tightening ${lex_his} chest as ${lex_she} clenches ${lex_his} fists, struggling to keep ${lex_his} emotions in check.

*page_break
Just before they reach the door to $!{name}'s office, Klemens pauses and meets ${lex_name}'s gaze with a strange, uneasy intensity.

"…Thank you," ${man_she} says simply, ${man_his} eyes betraying a familiar yet indefinable anxiety that makes ${lex_name} feel almost apprehensive.

$!{lex_she} knows Klemens enough to regard ${man_him} as a friendly acquaintance from the days when $!{name} was undergoing advanced training.

During that time, ${lex_name} did ${lex_his} best to support ${lex_his} friend, and Klemens's easygoing nature made it hard not to respond in kind whenever they ran into each other.

But now, as ${lex_she} catches Klemens's worried glance filled with something more prolonged than casual concern, ${lex_name} once again grows suspicious. 
[i]Why does Klemens care so much about $!{name}?[/i]

But ${lex_name} never asked about it directly, and it certainly won't happen today or ever; $!{name} is ${lex_his} priority, 
and the fact that Klemens reached out to ${lex_him} is enough to ignore all the rest.

That's why ${lex_name} simply nods in response, and Klemens's shoulders relax as ${man_she} finally opens the door.

*page_break
Just a glimpse of $!{name} from the doorway is enough for ${lex_name} to see that something is wrong: ${mc_she} is slumped in ${mc_his} chair, 
${mc_his} forehead resting in ${mc_his} palm, a throw blanket draped over ${mc_his} shoulders as ${mc_his} gaze remains fixed on a report on the desk.

A second later, $!{name} looks up slowly, ${mc_his} eyes glassy with a tired, almost sickly glint that betrays ${mc_his} exhaustion.

$!{lex_his} worry overtakes ${lex_him}, and ${lex_she} quickly steps inside. "$!{name}…"

"${lex_name}?" $!{mc_she} slowly @{plural rise|rises} from the chair, shifting ${mc_his} to the doorway, where Klemens remains standing.

"Alright, alright, that's enough for today, $!{name}. Wrap it up," Klemens says as ${lex_name} strides past ${man_him}, heading toward ${lex_his} friend.

"But I—"

"That's an order. We'll continue tomorrow, and I don't want you here in fifteen minutes," Klemens says with a hint of amusement in ${man_his} voice, 
yet it does nothing to hide ${man_his} concern. After a momentary pause, ${man_she} adds more softly, "Take a good rest, $!{name}."

Klemens doesn't wait for ${mc_his} response, and ${lex_name} hears ${man_his} footsteps receding as ${lex_his} focus remains solely on ${lex_his} friend.

*page_break
$!{name} frowns, turning ${mc_his} attention to ${lex_him}. "${lex_name}, why—"

Without a single word, ${lex_name} reaches out, placing a hand on ${mc_his} forehead and scowling at the heat when, unexpectedly for ${lex_him}, $!{name} leans into ${lex_his} touch, 
${mc_his} eyes fluttering closed.

$!{lex_his} heart skips a beat, but ${lex_she} forces ${lex_him}self to focus, slowly removing ${lex_his} hand.

"Why are you working when you're sick? You should have taken a day off," ${lex_she} says, ${lex_his} voice rising despite ${lex_his} efforts to stay calm.

$!{name} sighs, averting ${mc_his} gaze. "I have a lot of work to do, you know…" $!{mc_his} eyes drift to the cluttered desk, piled with folders and reports.

${lex_name}'s fists clench as ${lex_she} returns ${lex_his} gaze to $!{name}, who reaches for a pen ${mc_she} left on the desk. "I have three pages left, so—"

"$!{name}," ${lex_name} says firmly, causing ${mc_him} to look at ${lex_him} again. "You'll always have a lot of work to do," ${lex_she} continues, 
gently taking ${mc_his} hand and removing the pen from ${mc_his} grip. "But there will only ever be one of you for this work."

*page_break [i]One of you for me.[/i]
For a moment, they both look at their joined hands, and ${lex_name} gently squeezes before letting go and taking a step back, 
fearing that ${lex_his} feelings might cloud ${lex_his} judgment and cause ${lex_his} worried reaction to be met with rejection.

Even thinking about it makes ${lex_him} sick, but ${lex_she} can't afford this vulnerability, especially when it comes to $!{name}'s well-being. 

So ${lex_she} keeps ${lex_his} face calm and ${lex_his} tone firm as ${lex_she} says, "I'll give you a ride."

"You don't have to," $!{name} responded softly, setting aside ${mc_his} throw blanket as ${mc_she} @{plural reach|reaches} for ${mc_his} outerwear. "It's just a light fever, 
and Klemens really shouldn't have drugged you here," ${mc_she} @{plural add|adds}, 
a hint of irritation creeping into ${mc_his} voice as ${mc_she} carefully @{plural button|buttons} up ${mc_his} outerwear—
an action that doesnt't escape ${lex_name}'s notice.

*page_break
"Are you feeling a chill?" ${lex_name} asks, ignoring all ${mc_his} previous words.

"A little," $!{name} admits, switching off the lamp and gathering ${mc_his} things. "${lex_name}, you really don't have to give me a ride. 
I can get a cab, and I know you're tired after your shift."

"Oh, I'm aware of that too," ${lex_name} replies with a small sigh, gently taking ${mc_his} belongings from ${mc_his} hands. "Now stop being so stubborn and let me help," ${lex_she} says, 
${lex_his} tone calm but firm enough to make $!{name} pause.

Their eyes locked in a silent exchange, and after a moment, ${lex_name} noticed the subtle slump of $!{name}'s shoulders.

$!{lex_she} presses ${lex_his} lips together, realizing how much effort $!{name} must exert to keep it together. Yet, a selfish part of ${lex_him} swells with satisfaction, 
knowing $!{name} can finally relax because ${lex_she}'s here, and blending all ${lex_his} feelings with contentment and guilt.

${lex_name} knows how wrong it is to feel this way, and ${lex_she} wants to look away, but before ${lex_she} can avert ${mc_his} gaze, 
$!{name} sighs heavily and lowers ${mc_his} eyes, giving a silent nod.

In that instant, all of ${lex_his} conflicted thoughts are overshadowed by a deep sense of relief. Without hesitation, ${lex_she} stays close as they leave the department together.

*page_break …
[b]Now playing as yourself.[/b]

You wake to a gentle touch that sends a shiver of goosebumps across your skin. Instinctively, you lean into the warmth, 
seeking comfort from the cold that has seeped into your bones as you gradually become aware of ${lex_name}'s murmured voice.

"${name}…"

It takes a few groggy moments for your senses to sharpen, but soon you realize you're parked outside your house. [i]Had I really slept through the entire ride?[/i]

As you stir, you notice ${lex_name}'s coat draped over you. You smile tiredly, turning to meet ${lex_his} gaze.

"Thank you," you say quietly, offering the coat back to ${lex_him}.

$!{lex_his} fingers brush yours as ${lex_she} takes the coat, and you spot a plastic bag near ${lex_his} seat that wasn't there before. 

Curiosity stirs within you as you glance at the contents, and recognizing what's inside makes you look back at your friend with a sudden surge of vulnerability.

"I stopped by the drugstore to pick up something in case you didn't have anything that might help," ${lex_name} explains before you can ask, 
stepping out of the car with the package. "Come on."

*page_break As ${lex_she} closes the door behind ${lex_him}, you hesitate.
You've always loathed feeling weak and vulnerable, but right now, you're overwhelmed by the realization of everything ${lex_name} has done for you—both now and in the past. $!{lex_she}'s been there for you in a way that no one else has, especially since your sister moved to Ashborne and after your aunt—

[i]No use to think about it,[/i] you remind yourself as a bitter lump forms in your throat. Clenching your jaw to keep your emotions in check, you follow ${lex_name} outside, only to meet ${lex_his} tender gaze that cuts through all your defenses.

Just a fleeting moment of eye contact is enough to make you feel everything you've been trying to hide: exhaustion, cold, a flood of memories, gratitude, and something deeper—something only ${lex_name} has ever been able to evoke in you.

The fatigue weighs so heavily on you that you can't summon the energy to express all the thoughts swirling in your mind. Instead, you focus on ${lex_name}'s gentle hand on your back as ${lex_she} guides you toward the house.

*page_break
Once you cross the threshold, all your worries dissolve into the comforting embrace of home, feeling your strength wanes completely.

With slow, heavy movements, you peel off your outer layers. ${lex_name} helps you to your room and onto your bed. You sink into its softness, 
too drained to change, your body aching from the strain.

In a daze, you watch ${lex_him} leave only to return a minute later with a glass of dissolved medication.

You drink it silently, and as ${lex_name} takes the glass from your hand, you barely register ${lex_his} words before your eyelids grow too heavy to keep open.

You close your eyes, focusing on the warmth of ${lex_his} touch as it gently lingers, refusing to let go.

*page_break …
[b]Later…[/b]

It's still dark when you open your eyes, and your eyelids are heavy as you wait for your vision to adjust. 

After a moment, you finally notice ${lex_name} sitting on the floor beside your bed, leaning against the side with ${lex_his} fists clenched tightly.

"You didn't leave…" you croak, your voice hoarse from sleep, and ${lex_name} slowly turns ${lex_his} head towards you.

"How are you feeling?" ${lex_she} asks softly, ${lex_his} voice rough.

"Tired. Cold…" you reply, noticing that, in addition to the blanket, you're covered by a bedspread. "How long have you been sitting like this?" you ask, 
trying to understand ${lex_his} expression but failing to see clearly in the darkness.

"Not long," ${lex_she} answers after a moment, ${lex_his} voice uncharacteristically flat as ${lex_she} looks away. "It just reminded me of that time when you stayed by my side all night…" 

"You were in worse shape then," you murmur, frowning as you recall the past at the academy. "And that was a long time ago…"

*page_break 
${lex_name} doesn't respond, and once again, you feel fatigue and coldness constrict your consciousness. 

Before that can happen, you reach out, gently stroking ${lex_his} shoulder in a silent attempt to convey the gratitude that's so difficult to articulate.

$!{lex_she} turns back to you, ${lex_his} hand enveloping yours in a warm grasp that sends a shiver of comfort through your body.

"Thank you… for everything," you finally say, though the words feel lacking.

${lex_name} squeezes your hand reassuringly. "You don't have to thank me, ${name}. Just… please get better. And if you need anything, don't hesitate to ask me," ${lex_she} says, 
${lex_his} voice a mixture of exhaustion and sincerity that tugs at your heart. "I'm not asking for more than that."

A heavy silence settles between you, filled with unspoken longing. Your weary mind struggles to process ${lex_his} words as you lie there, 
feeling the cold and fatigue mingling with the warmth of ${lex_his} presence.

*page_break
There's no distance between you now, no barriers left to maintain. You're so tired, so cold, 
and ${lex_name}'s presence is the only thing filling the emptiness within you with something bright and comforting. 

It feels both right and wrong, but at this moment, it doesn't matter because…

"I need you to stay," you whisper, and almost immediately, ${lex_name} turns to you sharply.

For a heartbeat, you're gripped by the fear that it's too late to take back your words, but ${lex_she} doesn't give you the chance to second-guess yourself.

$!{lex_she} rises to ${lex_his} feet only to climb into bed beside you, pulling you tightly against ${lex_him}.

Your heart skips a beat as you instantly feel the warmth of ${lex_his} embrace.

*page_break [i]Is this a dream?[/i]
[i]If it is a dream, then…[/i]

Your body relaxes into ${lex_his} hold, continuing to shiver slightly as you close your eyes, surrendering to the soothing comfort you desperately need and crave.

"You're going to get sick too," you mumble, @{L_gen nestling into ${lex_his} chest|nuzzling into the curve of ${lex_his} neck}.

${lex_name} chuckles softly, a sound that warms your heart as ${lex_she} says, "I'll survive…"

$!{lex_she} says something else, but you can only hear the steady rhythm of ${lex_his} heartbeat, lulling you back to sleep despite your efforts to stay awake and savor this fleeting moment.

[i]For just a little while longer[/i], you think as sleep finally overtakes you.

*page_break …
*ending